Backyard — 4 of 15

Part 3 - Things

Some half-eaten boards are in the fence. the half-eaten boards can be infested or vermin-free. They are infested. The description of the half-eaten boards is "Something has bored lots of tiny holes all through them.[if infested] In fact, the quiet scritching indicates it isn't done yet.[otherwise] You get the feeling these could be transformed into something useful.". Understand "rotten" and "eaten" as half-eaten boards. The half-eaten boards are undescribed.

After examining the half-eaten boards for the first time:

now the half-eaten boards are described.

Instead of listening to the half-eaten boards, say "[if infested]... chomp ... chomp ...[else] ...".

Some healthy boards are in the fence. The description of the healthy boards is "Reasonably solid wooden planks. You get the feeling these could be transformed into something useful.". The healthy boards are undescribed.

After examining the healthy boards for the first time:

now the healthy boards are described.

Some needles are here. "Pine needles are scattered through the grass." The description of the needles is "There's quite a lot of them, but it wouldn't be too hard to gather them all.".

A bunch of twigs is a thing. The description of the bunch of twigs is "A good handfull of thin twigs.". Understand "twigs" as the bunch of twigs.

Some tools are a thing. The description of the tools is "Pretty much everything you'd need for small projects.".

Understand "use [tools]" or "use [tools] on [something]" or "build [text] from [something]" or "build [text] out of [something]" as a mistake ("If you want to build something, try to TRANSFORM a likely-looking material instead.").

Some reed stems are a thing. The description of the reed stems is "Strong and bendy, they urge you to weave them into something.". Understand "reeds" as reed stems.

Some mud is a thing. The description of mud is "Blobs of grainy oozy muck.".

A scythe is in the tree. The description of the scythe is "A classic scythe with a sharp blade." The scythe is undescribed.

Instead of taking the scythe when the scythe is in the tree, say "You think you might be able to free it if you climb high enough.".

The grass-weed is a privately-named thing in the Backyard. It is undescribed.

Instead of cutting the grass when the grass-weed is in location:

if the player is carrying the scythe:

say "You cut all grass in the yard. In the process you pick up several tools that had apparently been lost over the time.";

now the grass-weed is nowhere;

now the player carries the tools;

otherwise:

say "You don't have anything to cut it with.".

Instead of cutting the grass, say "The grass doesn't need cutting for now.".

Instead of cutting the reeds:

if the player is carrying the scythe:

say "The reeds have been hiding a small pond. You've discovered that fact by sinking into it up to your waist; your pockets are still full of mud.";

now the reeds are nowhere;

now the pond is in the location;

now the player carries the reed stems;

now the player carries mud;

otherwise:

say "You don't have anything to cut them with.".

Some gardening equipment is a thing. The description of the gardening equipment is "A hoe, shovel, clippers, and several other implements you don't know the proper names for; pretty much everything you need for gardening.".

The garden bed is a growing-place. "[if the garden bed produces something]A garden bed full of [produce of the bed][otherwise]An empty garden bed[end if] lies in the middle of the lawn." It is fixed in place. Understand "grass" and "lawn" as the garden bed. The description of the garden bed is "A nice small garden bed. [produce state of the garden bed]". It is nowhere.

Instead of landscaping the grass:

if the player is not carrying the gardening equipment:

say "You have no tools for that. It would be a nice place for a garden bed, though.";

otherwise:

say "You prepare a nice garden bed.";

now the grass is nowhere;

now the garden bed is in location.

Instead of landscaping the grass when the grass-weed is in location, say "It would be a nice place for a garden bed, if the grass weren't so high.".

Some flower seeds are a seed. "Small nondescript seeds. You could put them in a garden bed." The product of the flower seeds are the flowers.

Some salad seeds are a seed. "Small nondescript seeds. You could put them in a garden bed." The product of the salad seeds is the salad-plant.

Some flowers are a plant. The flowers are undescribed. The description of the flowers is "[if shooty]Just seeds, but some are already sprouting.[end if][if unripe]A bunch of leafy stems.[end if][if ripe]Colorful blooms catch the eye.[end if][if butterfly is in the location] A butterfly [one of]flutters around the flowers[or]is sitting on one bloom[or]startles and takes of from a flower[or]hovers above the biggest bloom[then at random]." The flowers are seedy. Understand "flower" as the flowers. Understand "seeds" and "sprouts" as the flowers when the flower seeds are not in location and the flowers are shooty. Understand "stems" as the flowers when the flowers are unripe.

A bouquet is a thing. "A bunch of sweet-smelling flowers."

Salad-plant is a plant. The printed name of the salad-plant is "salad". The salad-plant is undescribed. The description of the salad-plant is "[if shooty]Just seeds, but some are already sprouting.[end if][if unripe]A smattering of small curled leaves.[end if][if ripe]Thick heads of crisp green leaves.[end if][if the salad-plant is munched] A slug [one of]is chomping away on one leaf[or]is busily dining[or]has eaten most of them, though[stopping].[end if][if the salad-plant is colonised] A slug is happily munching on the leaves." The salad-plant is seedy. Understand "salad" as the salad-plant. Understand "seeds" and "sprouts" as the salad-plant when the salad seeds are not in location and the salad-plant is shooty. Understand "leaves" as the salad-plant when the salad-plant is unripe. Understand "heads" as the salad-plant when the salad-plant is ripe.

The salad-plant can be munched, colonised or free. The salad-plant is free.

The salad-plant is edible.

Check eating a plant:

if the noun is not ripe, say "It's not ripe yet.".

Instead of inserting a seed (called a seedling) into the garden bed:

if the garden bed produces something, say "This bed is already occupied." instead;

say "You sow the seeds in the garden bed.";

now the seedling is nowhere;

now the product of the seedling is in location;

now the garden bed produces the product of the seedling.

Understand "plant [seeds] in [something]" and "sow [seeds] in [something]" as inserting it into.

Instead of inserting a seed into something (called a pot):

if the pot is not a container, say "The seeds won't probably grow well there.";

if the pot is scenery, say "Now, if you had a garden bed somewhere...".

Instead of taking a plant (called a victim) when the garden bed produces the victim:

if the victim is not ripe, say "[The victim] are not ripe yet." instead;

say "You harvest all the [victim].";

now the player carries the victim;

now the garden bed produces nothing.